【Curie Nano】Curie Nano BLE初学（一）

9robot

       之前没有自己开发过蓝牙，就用过HC-05串口蓝牙模块，学习蓝牙必须从头开始了，Curie Nano内部集成了低功耗蓝牙，方便实现互连。如果不学习如何使用Curie自带的蓝牙的话，感觉就是一种资源浪费。依葫芦画瓢，现在对于蓝牙的协议不了解，就先看自带的例子去学习。好在例子里有注释，这个例子通过手机蓝牙可以控制Curie Nano上的LED灯的亮灭，同时，也可以通过按钮的电平变化去控制LED。
       和蓝牙设置有关的部分在setup函数中，自己可以在loop函数中稍微改动一下就可以实现一些其他IO的控制等

1. #include <CurieBLE.h>
   
2. 
   
3. const int ledPin = 13; // set ledPin to on-board LED
   
4. const int buttonPin = 4; // set buttonPin to digital pin 4
   
5. 
   
6. BLEService ledService("19B10010-E8F2-537E-4F6C-D104768A1214"); // create service
   
7. 
   
8. 
   
9. // create switch characteristic and allow remote device to read and write
   
10. BLECharCharacteristic ledCharacteristic("19B10011-E8F2-537E-4F6C-D104768A1214", BLERead | BLEWrite);
    
11. // create button characteristic and allow remote device to get notifications
    
12. BLECharCharacteristic buttonCharacteristic("19B10012-E8F2-537E-4F6C-D104768A1214", BLERead | BLENotify); // allows remote device to get notifications
    
13. 
    
14. void setup() {
    
15.   Serial.begin(9600);
    
16.   pinMode(ledPin, OUTPUT); // use the LED on pin 13 as an output
    
17.   pinMode(buttonPin, INPUT); // use button pin 4 as an input
    
18. 
    
19.   // begin initialization
    
20.   BLE.begin();
    
21. 
    
22.   // set the local name peripheral advertises
    
23.   BLE.setLocalName("BtnLED");
    
24.   // set the UUID for the service this peripheral advertises:
    
25.   BLE.setAdvertisedService(ledService);
    
26. 
    
27.   // add the characteristics to the service
    
28.   ledService.addCharacteristic(ledCharacteristic);
    
29.   ledService.addCharacteristic(buttonCharacteristic);
    
30. 
    
31.   // add the service
    
32.   BLE.addService(ledService);
    
33. 
    
34.   ledCharacteristic.setValue(0);
    
35.   buttonCharacteristic.setValue(0);
    
36. 
    
37.   // start advertising
    
38.   BLE.advertise();
    
39. 
    
40.   Serial.println("Bluetooth device active, waiting for connections...");
    
41. }
    
42. 
    
43. void loop() {
    
44.   // poll for BLE events
    
45.   BLE.poll();
    
46. 
    
47.   // read the current button pin state
    
48.   char buttonValue = digitalRead(buttonPin);
    
49. 
    
50.   // has the value changed since the last read
    
51.   boolean buttonChanged = (buttonCharacteristic.value() != buttonValue);
    
52. 
    
53.   if (buttonChanged) {
    
54.     // button state changed, update characteristics
    
55.     ledCharacteristic.setValue(buttonValue);
    
56.     buttonCharacteristic.setValue(buttonValue);
    
57.   }
    
58. 
    
59.   if (ledCharacteristic.written() || buttonChanged) {
    
60.     // update LED, either central has written to characteristic or button state has changed
    
61.     if (ledCharacteristic.value()) {
    
62.       Serial.println("LED on");
    
63.       digitalWrite(ledPin, HIGH);
    
64.     } else {
    
65.       Serial.println("LED off");
    
66.       digitalWrite(ledPin, LOW);
    
67.     }
    
68.   }
    
69. }

复制代码

将代码编译烧写后，打开手机调试软件，打开蓝牙，连接成功后，通过写入0和非零的数就可以控制LED的亮灭，通过也可以查看按钮对应引脚的高低电平。点击向上的箭头后弹出发送数值的界面，写入0或1就可以看到LED对应的变化

。

上传一下调试软件，方便下载